温度・湿度・気圧測定デバイス作製【農業IoT・AgriTechデバイス開発#6】

function doGet(e) {
//下記のsheet_idは、ご自身のスプレッドシートのURL（例えば下のようなもの）
//https://docs.google.com/spreadsheets/d/XXXXXXXXXX/・・・
//からXXXXXXXXXXを格納してください。
//下記のsheet_nameはスプレッドシートの下部にあるシート名そのものを格納してください。
  let sheet_id = 'XXXXXXXXXX';
  let sheet_name = 'YYYYYYYYYY';
  var flag;

  if (!e.parameter || Object.keys(e.parameter).length == 0) {
    flag = 'NG'; //"e.parameterが存在しない"または"e.parameterが空"の場合はNG
  } else {
    var sheet_1 = SpreadsheetApp.openById(sheet_id).getSheetByName(sheet_name);
    var nextRow = sheet_1.getLastRow() + 1;
    var inputData = [];

    inputData[0] = new Date(); //日時
    inputData[1] = e.parameter.temp; //温度
    inputData[2] = e.parameter.humi; //湿度
    inputData[3] = e.parameter.pres; //気圧
    inputData[4] = e.parameter.lux; //照度

    var nextRange = sheet_1.getRange(nextRow, 1, 1, inputData.length);
    nextRange.setValues([inputData]);
    flag = 'OK';
  }
  return ContentService.createTextOutput(flag);
}

#include <M5Stack.h>
#include <WiFi.h>
#include <Wire.h>
#include <HTTPClient.h>
#include "M5UnitENV.h"
#include <M5_DLight.h>

SHT3X sht30;
QMP6988 qmp;
M5_DLight DLsensor;

const char* ssid = "xxxxxxxxxx"; //ご自身のWi-FiのSSIDを格納してください。
const char* password = "yyyyyyyyyy"; //ご自身のWi-Fiのパスワードを格納してください。
const char* deployid = "zzzzzzzzzz"; //GASでデプロイした時に受け取るデプロイIDを格納してください。

void setup() {
  M5.begin();
  Serial.begin(115200);
  Wire.begin();
  WiFi.begin(ssid, password);
  DLsensor.begin();

  while(WiFi.status() != WL_CONNECTED){
    delay(1000);
    M5.Lcd.print(".");
  }
  M5.Lcd.println("\nCONNECTED!");

  //温湿度センサーの初期化を可視化
  if (!sht30.begin(&Wire, 0x44)) {
    M5.Lcd.println("SHT30 not found");
  } else {
    M5.Lcd.println("SHT30 initialized");
  }
  //気圧センサーの初期化を可視化
  if (!qmp.begin(&Wire, 0x70)) {
    M5.Lcd.println("QMP6988 not found");
  } else {
    M5.Lcd.println("QMP6988 initialized");
  }
  //消費電力を小さくするために、ディスプレイをオフ
  delay(5000);
  M5.Lcd.sleep();
  M5.Lcd.setBrightness(0);
}

void loop() {
  M5.update();
  float temp = 0.0;
  float humi = 0.0;
  float pres = 0.0;
  int lux = 0;
  //温湿度を取得
  if(sht30.update()){
    temp = sht30.cTemp;
    humi = sht30.humidity;
  }
  //気圧を取得
  if(qmp.update()){
    pres = qmp.pressure;
  }
  //照度を取得
  DLsensor.setMode(ONE_TIME_H_RESOLUTION_MODE); //低消費電力モード ただし、getLUX()を呼び出す毎にリセット
  lux = DLsensor.getLUX();

  //Googleスプレッドシートに送信
  dataSendToGoogleSpreadsheet(temp, humi, pres, lux);
  delay(5000);
}

//スプレッドシートにデータを送信する関数
void dataSendToGoogleSpreadsheet(float temp, float humi, float pres, int lux) {
  HTTPClient http;
  String url = "https://script.google.com/macros/s/";
  url += deployid; //デプロイIDをurlに組み込む

  //以下は各データ（温度、湿度、気圧）をurlに組み込む
  url += "/exec?temp=";
  url += temp;
  url += "&humi=";
  url += humi;
  url += "&pres=";
  url += pres;
  url += "&lux=";
  url += lux;

  http.begin(url);
  int httpCode = http.GET(); //GETリクエストを送信して、サーバからのステータスコードを受け取る
  if(httpCode > 0){
    Serial.printf("[HTTP] status code is %d\n", httpCode); //ステータスコードを表示
    if(httpCode == HTTP_CODE_OK){
      String payload = http.getString(); //ステータスコードが200ならpayload(本文)を表示
      Serial.println(payload);
    }
  } else {
    Serial.printf("[HTTP] failed, error: %s\n", http.errorToString(httpCode).c_str()); //エラー内容を表示
  }
  http.end();
}