M5Stackに時間を表示したい！ 〜ネットワーク接続は難しい？【超初心者がIoT開発に挑んでみる#6】

#include <M5Stack.h>
#include <WiFi.h> //Wi-Fi接続に必要なライブラリ

const char* ssid = "ここにSSIDを入れる";  
const char* password = "ここにパスワードを入れる";

void setup(){
 M5.begin();
 WiFi.begin(ssid, password); //ここでSSIDを選択して、パスワードを入力するイメージ

 //Wi-Fiに接続できるまで待機する(Wi-Fiに接続されるとWiFi.status()がWL_CONNECTEDなる)
 //この部分は必須ではないと思いますが、あったほうが視覚的に接続されたことがわかります
 while (WiFi.status() != WL_CONNECTED) {
  delay(1000);
  M5.lcd.print("~"); //適当な文字を1秒ごとに表示するようにしている
 }
 M5.lcd.println("\nCONNECTED!");

 //Wi-Fi接続を切断する
 //この部分も必須ではないようですが、接続の必要がなければ切断した方がいいです
 WiFi.disconnect(true);
 WiFi.mode(WIFI_OFF);
}

#include <M5Stack.h>
#include <WiFi.h>
#include <time.h> //時刻情報を取得する際に使う構造体tmが定義されている

//使用する変数を定義
const char* ssid = "ここにSSIDを入れる";  
const char* password = "ここにパスワードを入れる";
const char* ntpServerName = "ntp.nict.jp";  //NTPサーバのアドレス

//※時間関係の変数は”秒”に直すことに注意
const long jst = 9 * 3600;  //日本時間はグリニッジ標準時から9時間=9×3600秒進んでいる
const int daylightOffset = 0; //サマータイム用の変数を設定する（今回は日本時間なので0に設定）

//printLocalTime()関数の役割は、取得した時刻情報を画面に表示すること
void printLocalTime() {
  struct tm timeInfo; //時刻情報を受け取る際に使うtime.hで定義されている構造体

/* 構造体tmの中身
（これは補足なのでコメントアウトしています。今回はsec, min, hour, mday, mon, yearのみ扱います。）
  struct tm {
    int tm_sec;    0~61秒(61秒は最大２秒の閏秒を考慮している模様)
    int tm_min;    0~59分
    int tm_hour;   0~23時
    int tm_mday;   1~31日
    int tm_mon;    0~11月(1月を0月としているので使う際は+1する必要がある)
    int tm_year;   年(1900年からの年数なので使う際は+1900とする必要がある) 
    int tm_wday;   日曜日を0とした日数(日=0、月=1、火=2、・・・土=6)
    int tm_yday;   1月1日からの日数(0~365)
    int tm_isdst;  サマータイム用（詳細は割愛）
}
*/
//時刻情報を取得できたら画面に時刻情報を表示する
  if (getLocalTime(&timeInfo)==true){ //timeInfoの前に"&"をつけるのはアドレスを渡すため
    M5.Lcd.setCursor(0, 10);
    M5.Lcd.printf("Date: %04d/%02d/%02d\n", timeInfo.tm_year + 1900, timeInfo.tm_mon+1, timeInfo.tm_mday);
    M5.Lcd.printf("Time: %02d:%02d:%02d\n", timeInfo.tm_hour, timeInfo.tm_min, timeInfo.tm_sec);
  }
}

void setup() {
  M5.begin();
  M5.Lcd.setTextSize(2);
  //WiFiに接続するための処理→ssidとpasswordを渡す
  WiFi.begin(ssid, password);

  //WiFiに接続できるまで待機する(Wi-Fiに接続されるとWiFi.status()がWL_CONNECTEDなる)
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    M5.lcd.print("~");  //表示するものは何でもいいです。今回は1秒ごとに"~"が表示されるようにしました。
  }
  //WiFiに接続できたらCONNECTED!を表示する
  M5.lcd.println("\nCONNECTED!");
  delay(1000);
  M5.lcd.fillScreen(BLACK);

  //NTPサーバから時間を取得する
  configTime(jst, daylightOffset, ntpServerName);
  printLocalTime();

  //WiFiを切断する
  WiFi.disconnect(true);
  WiFi.mode(WIFI_OFF);
}

void loop() {
  //上記で宣言したprintLocalTime関数を呼び出して時刻情報を表示
  printLocalTime();
  delay(1000);
}