日照時間の調査【農業IoT・AgriTechデバイス開発#3】

#include <M5Stack.h>
#include <M5GFX.h>
#include <M5_DLight.h>
#include <SD.h>

//ディスプレイ関連
M5GFX display; //インスタンス生成
M5Canvas canvas(&display); //引数は&displayで参照を渡す

//センサー関連
M5_DLight sensor; //インスタンス生成
uint16_t lux_data; //照度を格納する変数、uint_t型でメモリを節約
File csvFile;
char fileName[99];

void setup() {
  M5.begin();
  display.begin();
  sensor.begin();
  canvas.setTextDatum(MC_DATUM); //テキストの基準位置を中央に設定
  canvas.setColorDepth(1); //カラービット深度をモノクロ表示に設定（メモリ消費を抑える）
  canvas.setFont(&fonts::Orbitron_Light_24); //フォントを指定
  canvas.createSprite(display.width(), display.height()); //仮想画面(Sprite)を生成、引数はディスプレイの幅と高さ
  canvas.setPaletteColor(1, ORANGE); //フォントカラーを指定
  
  //SDカード内に"Data"というファイルがなければ作成する
  if (!SD.exists("/Data")) {
    SD.mkdir("/Data");
  }
  //
  snprintf(fileName, 99, "/Data/testFile.csv");

//SDカードにcsvファイルを作成して、項目を記入しておく
//今回はData_Noとlux[lx]
  if (SD.exists(fileName) == false) {
    csvFile = SD.open(fileName, FILE_APPEND);
    csvFile.print("Data_No,lux[lx]\n");
    csvFile.close();
    delay(1000);
  }
}

float interval_min = 1.0; //データ取得の間隔を分単位で指定する用の変数（今回は1分に１回測定）
char lux[40]; //照度を文字列にフォーマットするときの変数
int n = 0;  //測定回数を格納する変数

void loop() {
  //画面に測定データを表示する
  sensor.setMode(ONE_TIME_H_RESOLUTION_MODE); //低消費電力モード ただし、getLUX()を呼び出す毎にリセット
  lux_data = sensor.getLUX();
  snprintf(lux, sizeof(lux), "lux: %d", lux_data); //lux_data(float)をlux(char)フォーマットして格納
  canvas.fillSprite(BLACK); //背景を黒にリセット
  canvas.drawString(lux, 160, 120); //luxを画面に描画
  canvas.pushSprite(0, 0); //仮想画面の内容を実際の画面に送信して描画
  
  //csvファイルにデータ保存（詳細は参考記事にあります）
  csvFile = SD.open(fileName, FILE_APPEND);
  csvFile.print(n);
  csvFile.print(",");
  csvFile.print(lux_data);
  csvFile.print("\n");
  csvFile.close();
  n++;
  delay(interval_min*1000*60);
}