土壌センサーで水分量をモニタリングしたい【超初心者がIoT開発に挑んでみる#12】

#include <M5Stack.h>
#include <WebServer.h>
#include <Wire.h>
#include <WiFi.h>
#include <M5UnitENV.h>
#include "SHT3X.h"
#include <time.h>

SHT3X sht30;
File csvFile;

IPAddress ip;
WebServer server(80);
const char* ssid = "xxxxxxxxxx";         //ご自身のWi-FiのSSIDに書き換えてください
const char* pw = "yyyyyyyyyy";                //ご自身のWi-Fiのパスワードに書き換えてください
const char* ntpServerName = "ntp.nict.jp";  //NTPサーバのアドレス

const long jst = 9 * 3600;     //日本時間はグリニッジ標準時から9時間=9×3600秒進んでいる
const int daylightOffset = 0;  //サマータイム用の変数を設定する（今回は日本時間なので0に設定）

float tmp = 0.0;        //温度を格納する変数
float hum = 0.0;        //湿度を格納する変数
int samplingRate = 30;  //サンプリング間隔[min]
int samplingFlag = 0;   //サンプリングのタイミングを決める変数
int moisture = 0;       //土壌水分量を格納する変数

//PCに各データを送信する
void sendData() {
  String msg = "Temperature : ";
  msg += tmp;
  msg += "'C\n";
  msg += "Humidity : ";
  msg += hum;
  msg += "%\n";
  msg += "Moisture : ";
  msg += moisture;
  msg += "\n";
  server.send(200, "text/plain", msg);
}

//サーバが見つからなかった時に404を返す
void handleNotFound() {
  server.send(404, "text/plain", "File Not Found\n\n");
}

void setup() {
  Serial.begin(115200);
  M5.begin();
  M5.Lcd.begin();
  Wire.begin();
  WiFi.begin(ssid, pw);
  M5.Power.begin();
  pinMode(26, INPUT);
  dacWrite(25, 0);
  sht30.begin();

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print("*");
  }
  Serial.println("");

  //M5StackにIPアドレスを表示
  ip = WiFi.localIP();
  M5.Lcd.setTextColor(GREEN);
  M5.Lcd.setTextSize(4);
  M5.Lcd.setCursor(10, 10);
  M5.Lcd.println("IP : ");
  M5.Lcd.println(ip);
  server.on("/", sendData);
  server.onNotFound(handleNotFound);
  server.begin();

  //microSDカードにDataファイルがなければ作成する
  if (!SD.exists("/Data")) {
    SD.mkdir("/Data");
  }
  configTime(jst, daylightOffset, ntpServerName);
}

void loop() {
  struct tm timeInfo;
  //時刻を取得できなかった場合にM5Stackの画面に表示
  if (!getLocalTime(&timeInfo)) {
    M5.Lcd.printf("Failed to obtain time(>.<)");
    return;
  }
  char fileName[99];
  //csvファイル名は何でも大丈夫です
  snprintf(fileName, 99, "/Data/cherryTomato_envData.csv");

  if (SD.exists(fileName) == false) {
    csvFile = SD.open(fileName, FILE_APPEND);
    csvFile.print("Year,Month,Date,hour,min,sec,Temperature,Humidity,Moisture\n");
    csvFile.close();
    delay(1000);
  }

  //tmp変数に温度、hum変数に湿度を格納する
  if (sht30.update()) {
    tmp = sht30.cTemp;
    hum = sht30.humidity;
  }
  //moisture変数に土壌水分量を格納する
  moisture = analogRead(36);

  //csvファイルにデータを書き込む
  //書き込むタイミングは、時刻で決めていて、"分"が偶数かつ"秒"が0の時にしている
  if (timeInfo.tm_min % 2 == 0 && timeInfo.tm_sec == 0) {
    csvFile = SD.open(fileName, FILE_APPEND);
    csvFile.print(timeInfo.tm_year + 1900);
    csvFile.print(",");
    csvFile.print(timeInfo.tm_mon + 1);
    csvFile.print(",");
    csvFile.print(timeInfo.tm_mday);
    csvFile.print(",");
    csvFile.print(timeInfo.tm_hour);
    csvFile.print(",");
    csvFile.print(timeInfo.tm_min);
    csvFile.print(",");
    csvFile.print(timeInfo.tm_sec);
    csvFile.print(",");
    csvFile.print(tmp);
    csvFile.print(",");
    csvFile.print(hum);
    csvFile.print(",");
    csvFile.print(moisture);
    csvFile.print("\n");
    csvFile.close();
  }
  server.handleClient();
  delay(1000);
}